!include "MUI2.nsh"

Name "LOGAR Client"
OutFile "../dist/LOGAR-Client-Setup.exe"
InstallDir "$PROGRAMFILES64\LOGAR"
RequestExecutionLevel admin

!insertmacro MUI_PAGE_WELCOME
!insertmacro MUI_PAGE_DIRECTORY
!insertmacro MUI_PAGE_INSTFILES
!insertmacro MUI_PAGE_FINISH

!insertmacro MUI_UNPAGE_CONFIRM
!insertmacro MUI_UNPAGE_INSTFILES

!insertmacro MUI_LANGUAGE "English"

Section "Install"
    SetOutPath "$INSTDIR"
    File "../dist/Win_Client.exe"
    File "../compilation/nssm.exe"
    File /r "../dist/runtime"

    CreateDirectory "$COMMONAPPDATA\LOGAR"

    # Install and configure service via NSSM
    ExecWait '"$INSTDIR\nssm.exe" install LOGAR_Client "$INSTDIR\Win_Client.exe"'
    ExecWait '"$INSTDIR\nssm.exe" set LOGAR_Client AppDirectory "$INSTDIR"'
    ExecWait '"$INSTDIR\nssm.exe" set LOGAR_Client AppStdout "$COMMONAPPDATA\LOGAR\client.log"'
    ExecWait '"$INSTDIR\nssm.exe" set LOGAR_Client AppStderr "$COMMONAPPDATA\LOGAR\client_err.log"'
    ExecWait '"$INSTDIR\nssm.exe" start LOGAR_Client'

    WriteUninstaller "$INSTDIR\uninstall.exe"
SectionEnd

Section "Uninstall"
    ExecWait '"$INSTDIR\nssm.exe" stop LOGAR_Client'
    ExecWait '"$INSTDIR\nssm.exe" remove LOGAR_Client confirm'
    RMDir /r "$INSTDIR\runtime"
    Delete "$INSTDIR\Win_Client.exe"
    Delete "$INSTDIR\nssm.exe"
    Delete "$INSTDIR\uninstall.exe"
    RMDir "$INSTDIR"
SectionEnd